通达信主力进出升级指标公式
{指标介绍：
红线--多方线；绿线--空方线；黄线--反弹线；
红线上穿绿线，多方力量强，当红线拐头向下时主力止盈；
红线在0轴下方，反弹线上穿多方线可提前入场，避免追高。}
VAR1:=(HHV(HIGH,21)-C)/(HHV(HIGH,21)-LLV(LOW,21))*100-10;
VAR2:=(C-LLV(LOW,21))/(HHV(HIGH,21)-LLV(LOW,21))*100;
VAR3:=SMA(VAR2,13,8);
高位:90;
低位:0;
多方: SMA(VAR3,13,8),COLORRED,LINETHICK2;
空方: SMA(VAR1,21,8),COLORGREEN,LINETHICK2;
中轴:45;
{macd计算 - 只保留计算不显示图形}
DIF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIF,9);
MACD:=(DIF-DEA)*2;
{kdj计算 - 只保留J线}
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
J:3*K-2*D,COLORYELLOW,LINETHICK2;
{简化kdJ信号条件}
J线金叉:=REF(J,1)<REF(D,1) AND J>D; {J线上穿D线(金叉)}
J线低位拐头向上:=J<50 AND J>REF(J,1) AND REF(J,1)<REF(J,2); {J线在低位开始向上转折}
J线超买:=J>80; {J线高于80为超买区域}
J线死叉:=REF(J,1)>REF(D,1) AND J<D; {J线下穿D线(死叉)}
J线高位拐头向下:=J>50 AND J<REF(J,1) AND REF(J,1)>REF(J,2); {J线在高位开始向下转折}
{J线上穿红色线（多方线）}
J上穿多方:=crOSS(J,多方);
{MACD优化条件}
MACD水上:=DIF>0 AND DEA>0; {双线均在零轴上方}
MACD金叉:=CROSS(DIF,DEA); {DIF上穿DEA}
MACD死叉:=CROSS(DEA,DIF); {DIF下穿DEA}
MACD顶背离:=C>REF(C,1) AND DIF<REF(DIF,1); {价格创新高但MACD未创新高}
{综合买入条件 - 已去掉rsi条件}
强买入条件:=CROSS(45,空方) AND (MACD金叉 OR MACD水上) AND J线金叉;
一般买入条件:=CROSS(45,空方) AND (MACD水上 OR J线低位拐头向上);
{逃顶信号条件 - 已去掉RSI条件}
强逃顶条件:=(CROSS(90,多方) OR CROSS(空方,45)) AND (J线超买 OR J线死叉 OR MACD死叉);
一般逃顶条件:=J线高位拐头向下 AND (MACD顶背离 OR 多方>70);
{绘制买入信号}
DRAWTEXT(强买入条件,70,'强买入'),COLORRED;
DRAWTEXT(一般买入条件,60,'买入'),COLORYELLOW;
{绘制逃顶信号}
DRAWTEXT(强逃顶条件,85,'强逃顶'),COLORGREEN;
DRAWTEXT(一般逃顶条件,75,'逃顶'),COLORCYAN;
{保留原有减仓清仓信号}
DRAWTEXT(CROSS(90,多方),90,'减仓'),COLORGREEN;
DRAWTEXT(CROSS(45,多方),30,'清仓'),COLORGREEN;
{金叉死叉标记}
DRAWICON(J线金叉,J,1);
DRAWICON(J线死叉,J,2);
{J线上穿红色线标记 - 在交叉处标记向上箭头}
DRAWICON(J上穿多方,J,1);
通达信黎明之星选股指标公式
VARG1:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
VARG2:=crOSS(3*SMA(VARG1,3,1)-2*SMA(SMA(VARG1,3,1),3,1),MA(3*SMA(VARG1,3,1)-2*SMA(SMA(VARG1,3,1),3,1),2)) AND C>O;
VARG3:=((REF(C,3)-REF(C,1))/C)*100>6;
VARG4:= CLOSE>REF(CLOSE,1)*1.03 ;
VARG5:= REF(((H-O)/C)*100<2,1);
VARG6:=REF(C<O,2) AND REF(C<O,1);
VARG7:=((H-C)/C)*100<2 AND H>REF(H,1);
VARG8:=((REF(O,1)-REF(C,1))/C)*100>1;
VARG9:=((REF(O,2)-REF(C,2))/C)*100<9;
XXmacd:="MACD.MACD">REF("MACD.MACD",1) AND "MACD.MACD"<0;
黎明之星:VARG2 AND VARG3 AND VARG4 AND VARG5 AND VARG6 AND VARG7 AND VARG8 AND VARG9 AND XXMACD;
